home *** CD-ROM | disk | FTP | other *** search
/ Aminet 3 / Aminet 3 - July 1994.iso / Aminet / util / boot / AllAssigns.lha / AllAssigns.S < prev   
Encoding:
Text File  |  1992-09-02  |  5.0 KB  |  115 lines
  1. ******************************************************************************
  2. *
  3. *                             All assigns 1.0
  4. *
  5. *                          (c) 1994 Jan Skypala
  6. *
  7. *                  $VER: AllAssigns.s 37.1 (16 Feb 1994)
  8. *
  9. ******************************************************************************
  10.  
  11.                 incdir  'Include:'
  12.                 include 'exec/exec_lib.i'
  13.                 include 'dos/dos_lib.i'
  14.                 include 'dos/dos.i'
  15.  
  16. _SysBase        equ     4
  17.  
  18. ADDASSIGNS      set     1
  19. DEFERASSIGNS    set     1
  20. NORMALASSIGNS   set     1
  21.  
  22. Start           move.l  (_SysBase).w,a6
  23.                 lea     DosName(pc),a1
  24.                 moveq   #37,d0
  25.                 jsr     _LVOOpenLibrary(a6)     ;open dos.library
  26.                 beq.b   End
  27.                 move.l  d0,a6
  28.                 lea     Assigns(pc),a4          ;beginning of assign list
  29. Normal          IFD     NORMALASSIGNS           
  30. ;               lea     NormalAssigns(pc),a4
  31. .loop1          move.l  a4,d1                   ;dir to d1
  32.                 moveq.l #ACCESS_READ,d2
  33.                 jsr     _LVOLock(a6)            ;lock it
  34.                 move.l  d0,d2
  35. .loop2          tst.b   (a4)+                   ;move to next string
  36.                 bne.b   .loop2
  37.                 move.l  a4,d1                   ;that's the assign
  38.                 jsr     _LVOAssignLock(a6)      ;assign it
  39. .loop3          tst.b   (a4)+                   ;move behind this string
  40.                 bne.b   .loop3
  41.                 tst.b   (a4)                    ;is there another string?
  42.                 bne.b   .loop1                  ;yes => process it
  43.                 addq    #1,a4
  44.                 ENDIF
  45. Adds            IFD     ADDASSIGNS
  46. ;               lea     AddAssigns(pc),a4       ;beginning of addassign list
  47. .loop1          move.l  a4,d1                   ;dir to d1
  48.                 moveq.l #ACCESS_READ,d2
  49.                 jsr     _LVOLock(a6)            ;lock it
  50.                 move.l  d0,d2
  51. .loop2          tst.b   (a4)+                   ;move to next string
  52.                 bne.b   .loop2
  53.                 move.l  a4,d1                   ;that's the assign
  54.                 jsr     _LVOAssignAdd(a6)       ;assign it
  55. .loop3          tst.b   (a4)+                   ;move behind this string
  56.                 bne.b   .loop3
  57.                 tst.b   (a4)                    ;is there another string?
  58.                 bne.b   .loop1                  ;yes => process it
  59.                 addq    #1,a4
  60.                 ENDIF
  61. Defers          IFD     DEFERASSIGNS
  62. ;               lea     DeferAssigns(pc),a4     ;beginning of deferassigns list
  63. .loop1          move.l  a4,d2                   ;dir to d2
  64. .loop2          tst.b   (a4)+                   ;move to next string
  65.                 bne.b   .loop2
  66.                 move.l  a4,d1                   ;that's the assign
  67.                 jsr     _LVOAssignLate(a6)      ;assign it
  68. .loop3          tst.b   (a4)+                   ;move behind this string
  69.                 bne.b   .loop3
  70.                 tst.b   (a4)                    ;is there another string?
  71.                 bne.b   .loop1                  ;yes => process it
  72.                 ENDIF
  73.                 move.l  a6,a1                   ;no => close dos.library
  74.                 move.l  (_SysBase).w,a6
  75.                 jsr     _LVOCloseLibrary(a6)
  76. End             rts                             ;and return
  77. Version         dc.b    '$VER:AllAssigns 37.1',0
  78. DosName         dc.b    'dos.library',0
  79. Assigns         IFD     NORMALASSIGNS
  80. NormalAssigns   dc.b    'Work:ENV',0,'ENV',0
  81.                 dc.b    'Work:T',0,'T',0
  82.                 dc.b    'Work:Clipboards',0,'CLIPS',0
  83.                 dc.b    'S:',0,'REXX',0
  84.                 dc.b    'DEVS:Printers',0,'PRINTERS',0
  85.                 dc.b    'DEVS:Keymaps',0,'KEYMAPS',0
  86.                 dc.b    'Work:BitmapFonts',0,'FONTS',0
  87.                 dc.b    'Work:Locale',0,'LOCALE',0
  88.                 dc.b    0
  89.                 ENDIF
  90.                 IFD     ADDASSIGNS
  91. AddAssigns      dc.b    'Work:Intellifont',0,'FONTS',0
  92.                 dc.b    'SYS:Classes',0,'LIBS',0
  93.                 dc.b    0
  94.                 ENDIF
  95.                 IFD     DEFERASSIGNS
  96. DeferAssigns    dc.b    'LOCALE:Help',0,'HELP',0
  97.                 dc.b    'SYS:',0,'HD',0
  98.                 dc.b    'Work:GoldED',0,'GOLDED',0
  99.                 dc.b    'Work:GUIMake',0,'GUIMAKE',0
  100.                 dc.b    'Work:Include',0,'INCLUDE',0
  101.                 dc.b    'Work:Include',0,'INCLUDES',0
  102.                 dc.b    'Work:Text_Include',0,'TEXT_INCLUDE',0
  103.                 dc.b    'Work:DPaint',0,'Deluxe Paint',0
  104.                 dc.b    'Work:DPaint',0,'DPaintIV',0
  105.                 dc.b    'Work:',0,'JPEGTMP',0
  106.                 dc.b    'Work:Pascal',0,'PASCAL',0
  107.                 dc.b    'SYS:Tools/Commodities',0,'PowerCache',0
  108.                 dc.b    'Work:Source/Articles/HowToCode',0,'HowToCode',0
  109.                 dc.b    'Work:E/Sources',0,'E',0
  110.                 dc.b    'Work:E/Bin',0,'EC',0
  111.                 dc.b    'Work:E/Modules',0,'EMODULES',0
  112.                 dc.b    'Work:E/ModulesText',0,'ETEXTS',0
  113.                 dc.b    0
  114.                 ENDIF
  115.